100 REM ******************
110 REM **   DOMINION   **
120 REM ******************
130 REM
140 REM AV PETER OLIN
150 REM
160 CALL CLEAR
170 CALL SCREEN(7)
180 REM
190 REM   ** VIT SPELARE **
200 CALL COLOR(9,16,1)
210 CALL CHAR(96,"FFFFFFFFFFFFFFFF")
220 REM
230 REM   ** SVART SPELARE **
240 CALL COLOR(10,2,1)
250 CALL CHAR(104,"FFFFFFFFFFFFFFFF")
260 REM
270 REM   ** BLA VAGGAR **
280 CALL COLOR(11,5,1)
290 CALL CHAR(112,"FFFFFFFFFFFFFFFF")
300 REM
310 REM   ** RITA RAM **
320 CALL HCHAR(1,2,112,31)
330 CALL HCHAR(24,2,112,31)
340 CALL VCHAR(1,2,112,24)
350 CALL VCHAR(1,32,112,24)
360 REM  ** SS=SVARTS SKOTT SV = VITS SKOTT VARIERAR MELLAN 0 OCH 5
370 SS=INT(RND*6)
380 SV=INT(RND*6)
390 REM ** STARTPOSITIONER RPS,KPS=SVARTS RAD&KOLUMN RPV,KPB=VITS KOLUMN
400 RPS=10
410 KPS=27
420 RPV=11
430 KPV=7
440 REM ** STARTRIKTNINGAR XVI,YVI=VITS HASTIGHETER I X- RESP.Y-LED
450 REM ** XSI,YSI=SVARTS HASTIGHETER I X- RESP. Y-LED
460 YVI=0
470 XVI=1
480 XSI=-1
490 YSI=0
500 REM ** BORJA SPELET **
510 REM R O D
520 CALL JOYST(1,XV,YV)
530 IF (XV=0)*(YV=0) THEN 570
540 REM IF (XV<>0)*(YT<>0) THEN 470
550 XVI=XV/4
560 YVI=YV/-4
570 RPV=RPV+YVI
580 KPV=KPV+XVI
590 CALL KEY(1,K,S)
600 IF (SV>0)*(K>-1) THEN 970
610 CALL GCHAR(RPV,KPV,DOT1)
620 CALL VCHAR(RPV,KPV,96)
630 IF DOT1<>32 THEN 780
640 REM S V A R T
650 CALL JOYST(2,XS,YS)
660 IF (XS=0)*(YS=0) THEN 700
670 REM IF (XS<>0)*(YS<>0) THEN 580
680 XSI=XS/4
690 YSI=YS/-4
700 RPS=RPS+YSI
710 KPS=KPS+XSI
720 CALL KEY(2,K1,S1)
730 IF (SS>0)*(K1>-1) THEN 1010
740 CALL GCHAR(RPS,KPS,DOT2)
750 CALL VCHAR(RPS,KPS,104)
760 IF DOT2<>32 THEN 850
770 GOTO 520
780 REM  ** C R A S H **
790 PTSS=PTSS+1
800 FOR I=1 TO 30
810 CALL VCHAR(RPV,KPV,112)
820 CALL VCHAR(RPV,KPV,32)
830 NEXT I
840 GOTO 900
850 PTSV=PTSV+1
860 FOR I=1 TO 30
870 CALL VCHAR(RPS,KPS,104)
880 CALL VCHAR(RPS,KPS,112)
890 NEXT I
900 REM
910 PRINT "VIT ";PTSV,"SVART ";PTSS
920 IF (PTSV=5)+(PTSS=5) THEN 1040
930 CALL KEY(1,A,B)
940 CALL KEY(2,C,D)
950 IF (A>-1)*(C>-1) THEN 160 ELSE 930
960 REM ** VIT SKJUTER **
970 CALL HCHAR(RPV,KPV,32)
980 SV=SV-1
990 GOTO 610
1000 REM ** SVART SKJUTER **
1010 CALL HCHAR(RPS,KPS,32)
1020 SS=SS-1
1030 GOTO 740
1040 END